|
众所周知，VB 的功能没有 VC++、Delphi 这样的全功能开发平台强大，但她也足以完成我们绝大部分的工作，只要你开动脑筋，敢想敢干，我们可以让 VB 发挥最大的效能，做出许多令人惊叹的软件。开发高难度软件，并不只是 VC++ 和 Delphi 的专利！
过去普遍认为 VB 无法自定义拦截 Windows 的消息，只能靠 VB 本身提供的几个有限的事件来编程，这有很大的局限性。缺少消息捕获，同时又被认为不支持回调函数机制（主要是因为 VB 没有指针，更谈不上函数指针），这造成了 VB 编程的很大局限性。事实上，VB 可以采用别的办法变相地实现这一机制。从 VB 5.0 开始就提供了 AddressOf 操作符，利用这个操作符可以获取 VB 自定义函数的地址。有了函数地址就可以采用回调函数的机制了。当然，VB 仍然无法实现 VB 函数之间的地址传递，她只支持 VB 函数到 DLL 的函数抵制传递。但是，这已经足够了。下面这个程序，就是采用了这一方法，程序中只有一个主窗体，通过设置属性，使得主窗体没有边框，没有标题栏，不能改变大小，不能通过标题栏托动。但是通过拦截 Windows 消息可以使得鼠标处在窗体中的任意位置都可以托动它，就像按住标题栏托动一样。这个程序没有用到任何附加的控件，全部采用 VB 代码完成。注意，请增加一个公共模块，以便声明一些函数和常数。以下代码在 VB 6.0 中通过。
'''' ===================================
'''' 这是公共模块的代码
Attribute VB_Name = "Module1"
Option Explicit
Public Const WM_NCHITTEST = &H84
Public Const VK_LBUTTON = &H1
Public Const HTCAPTION = 2
Public Const HTCLIENT = 1
Public Declare Function GetAsyncKeyState Lib "user32" (ByVal vKey As Long) As Integer
Public Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal hwnd As Long, ByVal Msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Public Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Public Const GWL_WNDPROC = -4
Global lpPrevWndProc As Long
Global gHW As Long
'''' 这里是关键，我自定义了一个窗口函数（回调函数），以替代 VB 窗体自己的默认窗口函数。'''' 窗口函数是干什么的？它就是负责处理 Windows 发送给它的消息，并加以过滤，筛选出它感兴趣'''' 的消息，映射成为事件供我们使用。VB 中每个窗口都有一个默认的窗口函数，我们是看不到的。'''' 有很多消息都被 VB 的默认窗口函数过滤掉了。了解 C/C++/Delphi 程序设计的朋友应该知道这些。
Function WindowProc(ByVal hw As Long, ByVal uMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
'''' 我们也进行消息过滤，不过我们指拦截我们感兴趣的消息
'''' 其他消息我们懒得处理，交给 VB 默认的窗口函数去处理吧。
Select Case uMsg
Case WM_NCHITTEST '''' 拦截 WM_NCHITTEST 消息
If GetAsyncKeyState(VK_LBUTTON) < 0 Then '''' 是否有鼠标左键在窗体客户区按下？
'''' 如果是，函数返回值被设置为 HTCAPTION，欺骗 Windows，让它以为鼠标是按在标题栏
'''' Windows 是通过窗口函数的返回值进行判断处理的
WindowProc = HTCAPTION
Exit Function
Else
'''' 其他的我们不管，还是规规矩矩的该怎么样就怎么样
WindowProc = HTCLIENT
Exit Function
End If
End Select
'''' 这里又是关键，因为其他我们不关心的消息我们自己不处理，所以必须由 VB 的默认处理函数处理
'''' lpPrevWndProc 其实就是一个函数指针，它指向 VB 默认窗口函数
WindowProc = CallWindowProc(lpPrevWndProc, hw, uMsg, wParam, lParam)
End Function
'''' ===================================
'''' 这是窗体的代码
VERSION 5.00
Begin VB.Form Form1
BorderStyle = 0 ''''None
ClientHeight = 3195
ClientLeft = 0
ClientTop = 0
ClientWidth = 4680
LinkTopic = "Form1"
MaxButton = 0 ''''False
MinButton = 0 ''''False
ScaleHeight = 3195
ScaleWidth = 4680
ShowInTaskbar = 0 ''''False
StartUpPosition = 3 ''''窗口缺省
Begin VB.CommandButton Command1
Caption = "Command1"
Height = 375
Left = 2160
TabIndex = 0
Top = 720
Width = 1575
End
End
Attribute VB_Name = "Form1"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Private Sub Command1_Click()
Unload Me '''' 按下这个按钮就退出了
End Sub
Private Sub Form_Load()
gHW = Me.hwnd '''' 保存窗体的句柄
'''' 下面是关键，完成两个工作：1、将我们自己的全局函数替换为新的窗体回调函数
'''' 2、保存原来的 VB 默认窗户口函数地址
lpPrevWndProc = SetWindowLong(gHW, GWL_WNDPROC, AddressOf WindowProc)
End Sub
其实，一切就这么简单。有了这种办法，Windows 中需要回调函数的 API 函数我们都可以调用了，有很多的功能我们都可以用 VB 来实现了。注意，我们自定义的回调函数只能是模块中定义的全局函数！不能在窗体中定义。
写出来只是想抛砖引玉，其实有很多功能不需要到处去找控件的。我现在在研究用 VB 6 + DirectX 7/8 写游戏。游戏速度当然不可能达到 C++ 的程度，但是足够应付一些中小型的游戏题材了，比如 RPG 的。这又有很多值得写出来的了。虽然不是什么新鲜的话题，但是其中仍不乏许多的技巧和编程思想。希望对此有研究的朋友能够多多出来交流指点一二。
[VB.NET程序]GSM短信模块库函数，可以用VB,VC,调用简单实用 [办公软件]PowerPoint做交互课件之弃用VBA
[办公软件]VBA获取U盘、主板、CPU序列号和网卡MAC地址 [办公软件]VBA设置文件属性及加密源代码示例
[办公软件]VBA中初始化ADO连接的几种方法 [网络安全]“VB破坏者变种N”病毒摘要
[Web开发]ASP.NET上传文件到数据库VB版 [办公软件]在Excel中利用VBA实现多表单元格数据的读取与赋值…
[办公软件]使用Vba读取已关闭的Excel工作薄数据到当前工作表… [办公软件]Excel编程基础之VBA文件操作详解
| 
注：本站部分文章源于互联网，版权归原作者所有！如有侵权，请原作者与本站联系，本站将立即删除！ 本站文章除特别注明外均可转载，但需注明出处！ [MinTao学以致用网] 
