转至繁体中文版     | 网站首页 | 图文教程 | 资源下载 | 站长博客 | 图片素材 | 武汉seo | 武汉网站优化 | 
最新公告:     敏韬网|教学资源学习资料永久免费分享站!  [mintao  2008年9月2日]        
您现在的位置: 学习笔记 >> 图文教程 >> 站长学院 >> Web开发 >> 正文
一个关于ASP运行时间计算的代码         ★★★

一个关于ASP运行时间计算的代码

作者:闵涛 文章来源:闵涛的学习笔记 点击数:2364 更新时间:2013/2/2 15:04:06
一个关于ASP运行时间计算的代码

以下是代码片段:
<%
dim end_time,time_ijob
end_time=timer()
time_ijob=FormatNumber((end_time-startime),2)
if time_ijob<1 then
response.write "执行时间:<font color=""#ff0000"">0"&time_ijob&"</font>秒"
else
response.write "执行时间:<font color=""#ff0000"">"&time_ijob&"</font>秒"
end if
%>


\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
Class ccClsProcessTimeRecorder
''ASP程序代码执行时间统计类

 Private ccInti,ccIntNonceTime,ccIntDecimal
 Private ccIntStartTime,ccIntEndTime,ccIntNow,ccIntNonce
 Private ccStrInterval,ccStrEvent,ccStrTime,ccStrStatisticLog,ccStrFormatInterval
 Private ccArrEvent,ccArrTime

 Private Sub Class_Initialize
   ccStrInterval = "|"  ''默认分隔符
   ccIntDecimal = 4    ''小数点后位数
   ccStrEvent = ""
   ccStrTime = ""
   ccStrFormatInterval = "<br />" & vbCrLf
   ccIntStartTime = Timer
   ccIntNow = ccIntStartTime
   ccIntNonce = ccIntStartTime
 End Sub

 Public Sub Record(ccStrEventName)
   ccStrEvent = ccStrEvent & ccStrInterval & Replace(ccStrEventName,ccStrInterval,"")
   ccStrTime = ccStrTime & ccStrInterval & FormatNumber(Timer-ccIntNow,ccIntDecimal,True,False,True)
   ccIntNow = Timer
 End Sub

 Public Property Let Format(ccStrFormatType)
   If LCase(Trim(ccStrFormatType)) = "html" Then
     ccStrFormatInterval = "<br />" & vbCrLf
   Else
     ccStrFormatInterval = vbCrLf
   End If
 End Property

 Public Function Statistic
   If InStr(ccStrEvent,ccStrInterval) > 0 Then
     ccIntEndTime = Timer
     ccArrEvent = Split(ccStrEvent,ccStrInterval)
     ccArrTime = Split(ccStrTime,ccStrInterval)
     ccStrStatisticLog = ccStrStatisticLog & "Process Time Record" & ccStrFormatInterval
     ccStrStatisticLog = ccStrStatisticLog & "--------------------------------------" & ccStrFormatInterval
     For ccInti = 1 To UBound(ccArrEvent)
       ccStrStatisticLog = ccStrStatisticLog & ccArrEvent(ccInti) & " : " & ccArrTime(ccInti) & " s" & ccStrFormatInterval
     Next
     ccStrStatisticLog = ccStrStatisticLog & "--------------------------------------" & ccStrFormatInterval
     ccStrStatisticLog = ccStrStatisticLog & "Total : " & FormatNumber(ccIntEndTime-ccIntStartTime,ccIntDecimal,True,False,True) & " s"
     Statistic = ccStrStatisticLog
   Else
     Statistic = "No Record"
   End If
 End Function

 Public Function Nonce
   ccIntNonceTime = FormatNumber(Timer-ccIntNonce,ccIntDecimal,True,False,True)
   ccIntNonce = Timer
   Nonce = ccIntNonceTime
 End Function

 Public Function Total
   Total = FormatNumber(Timer-ccIntStartTime,ccIntDecimal,True,False,True)
 End Function

End Class

类属性:
1.Format
输出时是否带HTML换行标签
-html:输出HTML换行标签和文本换行符(默认)
-text:仅输出文本换行符

类方法:
1.Record("Code Name")
统计自上一次调用Record方法至现在的时间(第一次调用时统计声明类时至调用时时间),最后在Statistic中输出

类函数:(即时返回信息)
1.Nonce
输出自上一次调用nonce函数至现在的时间(第一次调用时统计声明类时至调用时时间)
2.Total
输出声明类到现在总时间
3.Statistic
输出所有Record统计信息和总程序时间

实例代码:

Dim objRecord,i,k,j,x

Set objRecord = New ccClsProcessTimeRecorder
objRecord.Format = "html"

For i = 1 To 100000
 x = 2 + 2
Next

Call objRecord.Record("加法")
For j = 1 To 100000
 x = 2 * 2
Next

Call objRecord.Record("乘法")

For k = 1 To 100000
 x = 2 ^ 2
Next

Call objRecord.Record("开方")

Response.Write objRecord.Statistic

输出:
Process Time Record
--------------------------------------
加法 : 0.0625 s
乘法 : 0.0469 s
开方 : 0.1094 s


[Web开发]ASP:检测含有中文字符串的实际长度  [Web开发]asp 中英文字符长度检测判断函数
[Web开发]安全维护 IIS asp 站点的高级技巧  [Access]ASP&SQL让select查询结果随机排序的实现方法
[Web开发]ASP字符串截取函数  [Web开发][asp]关键词只替换一次的写法
[Web开发]Asp无组件生成缩略图方法详解  [Web开发]asp编程中优化数据库方法详解
[Web开发]三种方法教你asp如何去除html标记  [Web开发]一段ASP防采集的代码,让小偷程序无处可采
教程录入:mintao    责任编辑:mintao 
  • 上一篇教程:

  • 下一篇教程:
  • 【字体: 】【发表评论】【加入收藏】【告诉好友】【打印此文】【关闭窗口
      注:本站部分文章源于互联网,版权归原作者所有!如有侵权,请原作者与本站联系,本站将立即删除! 本站文章除特别注明外均可转载,但需注明出处! [MinTao学以致用网]
      网友评论:(只显示最新10条。评论内容只代表网友观点,与本站立场无关!)

    同类栏目
    · Web开发  · 网页制作
    · 平面设计  · 网站运营
    · 网站推广  · 搜索优化
    · 建站心得  · 站长故事
    · 互联动态
    更多内容
    热门推荐 更多内容
  • 没有教程
  • 赞助链接
    更多内容
    闵涛博文 更多关于武汉SEO的内容
    An error occurred on the server when processing the URL. Please contact the system administrator.

    If you are the system administrator please click here to find out more about this error.

    | 设为首页 |加入收藏 | 联系站长 | 友情链接 | 版权申明 | 广告服务
    MinTao学以致用网

    Copyright @ 2007-2012 敏韬网(敏而好学,文韬武略--MinTao.Net)(学习笔记) Inc All Rights Reserved.
    闵涛 投放广告、内容合作请Q我! E_mail:admin@mintao.net(欢迎提供学习资源)

    站长:MinTao 信息产业部ICP备案号:鄂ICP备11006601号

    闵涛站盟:医药大全-武穴网A打造BCD……
    咸宁网络警察报警平台